Smalltalk/X GUI classes

The most heavily used interactor components are:

Button
Toggle
CheckToggle
CheckBox
RadioButton
ScrollBar

Button

The simplest push button. They may have either a string or image as buttonlabel. When pressed, they either perform a predefined action (action block) or send a change message to a model.

Typical uses:

using an action block:

    |top button|

    top := StandardSystemView new.
    top extent:100@100.

    button := Button label:'press me'.
    button origin:0.0@0.0 corner:1.0@1.0.
    button action:[Transcript showCR:'hello world'].

    top addSubView:button.
    top open.

with a model:

    |top button|

    top := StandardSystemView new.
    top extent:100@100.

    button := Button label:'press me'.
    button origin:0.0@0.0 corner:1.0@1.0.
    button model:Transcript; changeMessage:#flash.

    top addSubView:button.
    top open.

ArrowButton

These are typically used as components of a scrollBar.

Toggle

An on/off switch. These are like buttons, but toggle their state when clicked. Like buttons, they can be used with action blocks or alternatively with a model.

Typical use:

with an action block:

    |top toggle|

    top := StandardSystemView new.
    top extent:100@100.

    toggle := Toggle label:'press me'.
    toggle origin:0.0@0.0 corner:1.0@1.0.
    toggle action:[:state | Transcript showCR:'toggles state is: ' , state printString].

    top addSubView:toggle.
    top open.

CheckToggle

like above, with a check-mark. They are seldom used alone; instead, these are commonly found as a component in a checkBox.

CheckBox

combines a checkToggle with a label. Protocolwise, they behave much like toggles.

with an action block:

    |top toggle|

    top := StandardSystemView new.
    top extent:100@100.

    toggle := CheckBox label:'press me'.
    toggle origin:0.0@0.0 corner:1.0@1.0.
    toggle action:[:state | Transcript showCR:'toggles state is: ' , state printString].

    top addSubView:toggle.
    top open.

RadioButton

Like toggles, but these never turn themself off when clicked again. These are typically placed in a so called RadioButtonGroup, in which buttons turn off each other.

Scrollers, ScrollBars and Sliders

These are typically used as components of scrollable views. Except for sliders, these are seldom used isolated. Like buttons, these can be used either with an actionBlock or a changeMessage to its mdel (passing the scrollbars position as argument). A sliders value range defaults to 0..100, but can be changed as appropriate.

slider with action block:

    |top slider|

    top := StandardSystemView new.
    top extent:100@100.

    slider := HorizontalSlider new.
    slider start:200 stop:400.
    slider thumbOrigin:300.
    slider action:[:value | Transcript showCR:'sliders value state is: ' , value rounded printString].

    top addSubView:slider.
    top open.

<cg at exept.de>

Doc $Revision: 1.3 $ $Date: 2021/03/13 18:24:50 $